-- Шаблон создан мастером бланков
-- 05.12.2007 14:09:50
--
БланкСШаблоном "Импорт справочников";
--
--Процедуры и функции -------------
Func Загрузить(vCrd:S; vИмя:S; vSource:S):L;
var OWA,i:I;
var Flag:l;
 if not CanInsert(vCrd) or not CanDelete(vCrd) or IsReadOnly(vCrd): Message("Вы не обладаете достаточными правами для выполнения данной операции",mtError); ^False; fi;
 if not ExistFile(vSource+".cdf") or not ExistFile(vSource+".crd"): Message("Источник для загрузки не найден: "+vSource); ^False; fi;
 Try
  if Раб.Бюджет2005.Сетевая:
     i=Раб.Семафор.Статус(vCrd,0);
     if not i=0 then
        if i=1: Message("Операция уже выполняется пользователем "+Раб.Семафор.mUser,mtWarning); fi;
        ^False;
     fi;
     Раб.Семафор.Установить(vCrd,0,0,"",True,1.1.100,0);
     Flag=True;
  fi;
  OWA=OpenWorkArea(vCrd,"","");
  Try
   if not Records(OWA)=0:
      if EnqOkCancel("Картотека уже содержит загруженный справочник "+vИмя+", обновить ?",mtWarning)=cmCancel: ^False; fi;
   fi;
   DeleteAllRecords(OWA);
  Finally
   CloseWorkArea(OWA);
  end;
  if Раб.Бюджет2005.Сетевая:
     Раб.Семафор.Обновить(True,vCrd,0,0,"",True,1.1.100);
  fi;
  ImportCard(ieCRD, --Формат
             vCrd, --Картотека обязательное имя картотеки, в которую импортируется заданный файл
             vSource, --Файл полное или короткое имя файла со структурой заданной картотеки
             False, --ВидимПоля загружать только видимые поля (Истина) или все поля (Ложь)
             False, --Режим загружать поля CreateTime, UpdateTime, CreatedUser, ModifiedUser
             False, --DOS загружать текст в кодировке DOS (Истина) или в кодировке Windows (Ложь);
             True, --Подтв запрашивать подтверждения (Истина) или нет (Ложь).
             ovrNone, --Действ целочисленная константа для разрешения конфликтных ситуаций в импорте
             True, --Удал удалять содержимое картотеки (Истина) или нет (Ложь);
             True, --ПоказДиалог показывать диалог соответствия полей (Истина) даже
             False --Настройки логический параметр, определяющий, использовать ли настройки браузера картотеки при загрузке
            );
 Finally
  if Раб.Бюджет2005.Сетевая and Flag: Раб.Семафор.Снять(vCrd,true); fi;
 end;
 Message("Загрузка справочника "+vИмя+" завершена");
 ^True;
end;

Func ЕстьЗаписиОКДП:L;
var OWA:I;
 OWA=OpenWorkArea("РПО_ОКДП","");
 Try
  if Records(OWA)=0: 
     if EnqOkCancel("Справочник ОКДП не загружен. Загрузить ?",mtWarning)=cmOk:
        ^Загрузить("РПО_ОКДП","ОКДП",PlanVar("Std_Rpo")+"\DBF\РПО_ОКДП");
     fi;
     ^False;
  fi;
 Finally
  CloseWorkArea(OWA);
 end;
 ^True;
end;
--Процедуры и функции -------------                           
--
--
--Обработчики событий полей шаблона-----
--Обработчики событий полей шаблона-----
--
--Обработчики событий объектов шаблона-----
Proc Button_OnClick(Sender: String);
var Path:S;
 Path=PlanVar("Std_Rpo");
 if Sender="Button1": Загрузить("РПО_ОКВ" ,"ОКВ" ,Path+"\DBF\РПО_ОКВ");
   |Sender="Button2": Загрузить("РПО_ОКСМ","ОКСМ",Path+"\DBF\РПО_ОКСМ");
   |Sender="Button3": Загрузить("РПО_ОКЕИ","ОКЕИ",Path+"\DBF\РПО_ОКЕИ");
   |Sender="Button4": if Загрузить("РПО_ОКДП","ОКДП",Path+"\DBF\РПО_ОКДП"): 
                         Раб.Вспом.Импорт_Справ.СинхронОКДП(601); 
                         Раб.Вспом.Импорт_Справ.СинхронОКДП(273);
                      fi;
   |Sender="Button5": Загрузить("РПО_ОКВ" ,"ОКВ" ,Path+"\DBF\РПО_ОКВ"); 
                      Загрузить("РПО_ОКСМ","ОКСМ",Path+"\DBF\РПО_ОКСМ"); 
                      Загрузить("РПО_ОКЕИ","ОКЕИ",Path+"\DBF\РПО_ОКЕИ"); 
                      if Загрузить("РПО_ОКДП","ОКДП",Path+"\DBF\РПО_ОКДП"): 
                         Раб.Вспом.Импорт_Справ.СинхронОКДП(601); 
                         Раб.Вспом.Импорт_Справ.СинхронОКДП(273);
                      fi;
   |Sender="Button6": Загрузить("РПО_ОКП" ,"ОКП" ,Path+"\DBF\РПО_ОКП");
   |Sender="Button7": if ЕстьЗаписиОКДП: Раб.Вспом.Импорт_Справ.СинхронОКДП(601); fi;
   |Sender="Button8": if ЕстьЗаписиОКДП: Раб.Вспом.Импорт_Справ.СинхронОКДП(273); fi;
   |Sender="Button9": Загрузить("РПО_ОКПД","ОКПД",Path+"\DBF\РПО_ОКПД");
   |Sender="Button10": Загрузить("РПО_ОКВЭД","ОКВЭД",Path+"\DBF\РПО_ОКВЭД");
 fi;
end;

--Обработчики событий объектов шаблона-----
--
--
--Обработчики событий шаблона -----
--Обработчики событий шаблона -----
--


Конец

